; DMX Converter Code
;
; Speed: 8Mhz
; Input:  DMX 512 TTL Signal (250000 Baud)
; Output: PMX TTL Signal (9600 Baud)
; Target: AT90S2313
;
; Port B,0-7		-> 9x DIP (0-7)
; Port D,6			-> 9x DIP (8)
;
; Port D,0 (RxD)	-> 75176,Y
; Port D,1 (TxD)	-> NC
; Port D,2			-> Software UART PMX Out
; Port D,3			-> Lamp-Relais
; Port D,4			-> Manual Lamp On/Off
; Port D,5			-> DMX OK LED


.include "2313def.inc"

; Definitions

.equ		PMX				=2		;PMX Output Pin
.equ		LAMP			=3		;Lamp-Relais Output Pin
.equ		LAMP_SW			=4		;Manual Lamp On/Off Input Pin

.def		SREG_BACK		=r8
.def		POW_LOCK_COUNT_0=r10
.def		POW_LOCK_COUNT_1=r11
.def		POW_LOCK_COUNT_2=r12
.def		PMX_BYTE		=r16	;Actual PMX Byte to be transfered
.def		PMX_STATE		=r17	;(==0: No Transfer active; !=0: Actual Transfer Position)
.def		LAMP_POW_STATE	=r18
.def		LAMP_POW_LOCK	=r19
.def		DMX_IND			=r21
.def		DMX_STATE		=r22
.def		DMX_BYTE		=r23	;Wird nur im UART Interrupt verwendet
.def		INT_LOAD		=r23	;Wird nur in anderen Interrupts verwendet
.def		INT_TEMP		=r24	;Must be r24 because of an adiw Instruction
.def		TEMP			=r25	;Must be r25 because of an adiw Instruction
;			r26,r27  (X)   ->		 DMX Startadress
;			r28,r29  (Y)   ->		 Current DMX Adress



.org $0000
				;Interrupts
				rjmp	RESET
				reti
				reti
				reti
				reti
				rjmp	TIMER_1_OVF
				reti
				rjmp	RX_INT



TIMER_1_OVF:	in		SREG_BACK,SREG		;Save SREG
				ldi		INT_LOAD,0xFC
				out		TCNT1H,INT_LOAD			;Set Timer Count Registers to 104,166µS (High Register first!)
				ldi		INT_LOAD,0xCA
				out		TCNT1L,INT_LOAD
				cpi		PMX_STATE,0x00
				breq	TIMER_1_OF_EW
				cpi		PMX_STATE,0x01
				breq	TIMER_1_OF_ST0
				cpi		PMX_STATE,0x0A
				brsh	TIMER_1_OF_ST1
				cpi		PMX_STATE,0x02
				breq	TIMER_1_OF_BT0
				cpi		PMX_STATE,0x03
				breq	TIMER_1_OF_BT1
				cpi		PMX_STATE,0x04
				breq	TIMER_1_OF_BT2
				cpi		PMX_STATE,0x05
				breq	TIMER_1_OF_BT3
				cpi		PMX_STATE,0x06
				breq	TIMER_1_OF_BT4
				cpi		PMX_STATE,0x07
				breq	TIMER_1_OF_BT5
				cpi		PMX_STATE,0x08
				breq	TIMER_1_OF_BT6
				rjmp	TIMER_1_OF_BT7
TIMER_1_OF_EW:	rjmp	TIMER_1_OF_EXIT
TIMER_1_OF_BT0:	sbrs	PMX_BYTE,0
				cbi		PORTD,PMX
				sbrc	PMX_BYTE,0
				sbi		PORTD,PMX
				rjmp	TIMER_1_OF_INC
TIMER_1_OF_BT1:	sbrs	PMX_BYTE,1
				cbi		PORTD,PMX
				sbrc	PMX_BYTE,1
				sbi		PORTD,PMX
				rjmp	TIMER_1_OF_INC
TIMER_1_OF_BT2:	sbrs	PMX_BYTE,2
				cbi		PORTD,PMX
				sbrc	PMX_BYTE,2
				sbi		PORTD,PMX
				rjmp	TIMER_1_OF_INC
TIMER_1_OF_BT3:	sbrs	PMX_BYTE,3
				cbi		PORTD,PMX
				sbrc	PMX_BYTE,3
				sbi		PORTD,PMX
				rjmp	TIMER_1_OF_INC
TIMER_1_OF_BT4:	sbrs	PMX_BYTE,4
				cbi		PORTD,PMX
				sbrc	PMX_BYTE,4
				sbi		PORTD,PMX
				rjmp	TIMER_1_OF_INC
TIMER_1_OF_BT5:	sbrs	PMX_BYTE,5
				cbi		PORTD,PMX
				sbrc	PMX_BYTE,5
				sbi		PORTD,PMX
				rjmp	TIMER_1_OF_INC
TIMER_1_OF_BT6:	sbrs	PMX_BYTE,6
				cbi		PORTD,PMX
				sbrc	PMX_BYTE,6
				sbi		PORTD,PMX
				rjmp	TIMER_1_OF_INC
TIMER_1_OF_BT7:	sbrs	PMX_BYTE,7
				cbi		PORTD,PMX
				sbrc	PMX_BYTE,7
				sbi		PORTD,PMX
				rjmp	TIMER_1_OF_INC
TIMER_1_OF_ST0:	cbi		PORTD,PMX
				rjmp	TIMER_1_OF_INC
TIMER_1_OF_ST1:	sbi		PORTD,PMX
TIMER_1_OF_INC:	inc		PMX_STATE
				cpi		PMX_STATE,0x0E
				brlo	TIMER_1_OF_EXIT
				sbi		PORTD,PMX
				clr		PMX_STATE
TIMER_1_OF_EXIT:clr		INT_TEMP
				cp		POW_LOCK_COUNT_0,INT_TEMP
				cpc		POW_LOCK_COUNT_1,INT_TEMP
				cpc		POW_LOCK_COUNT_2,INT_TEMP
				breq	TIMER_1_OF_L_0
				clr		INT_LOAD
				ldi		INT_TEMP,0x01
				sub		POW_LOCK_COUNT_0,INT_TEMP
				sbc		POW_LOCK_COUNT_1,INT_LOAD
				sbc		POW_LOCK_COUNT_2,INT_LOAD
				rjmp	TIMER_1_OF_EX_1
TIMER_1_OF_L_0: clr		LAMP_POW_LOCK
TIMER_1_OF_EX_1:out		SREG,SREG_BACK
				reti



;UART Interrupts
RX_INT:			in		SREG_BACK,SREG          ;Save SREG
				in		DMX_BYTE,UDR            ;GET DMX_BYTE
				sbic	UCR,1                   ;Is Break?
				rjmp	NO_BREAK                ;No!
				ldi		YL,0x00                 ;Yes!
				ldi		YH,0x00
				cbr		DMX_STATE,1             ;Clr Wait_for_next_Break
				sbr		DMX_STATE,2             ;Set DMX_STATEwas_in_last_Frame
				rjmp	ENDE_RX_INT             ;Exit_Interruptroutine
NO_BREAK:		sbrc	DMX_STATE,0             ;Is Wait_for_next_Break set?
				rjmp	ENDE_RX_INT             ;Yes!
				sbrs	DMX_STATE,1             ;No!  -> Was there a Break in the last Frame?
				rjmp	DATA_BYTE_REC           ;No!  -> goto DATA_BYTE_REC
				tst		DMX_BYTE                ;Yes! -> Is DMX_BYTE = 0?
				brbc	1,WEITERLEITUNG         ;No! -> goto Set_Wait_for_DMX_STATEund_Exit
				cbr		DMX_STATE,2             ;Yes -> Clear DMX_STATEin_last_Frame Bit
				ldi		DMX_IND,0xFF
				rjmp	ENDE_RX_INT             ;and Exit Interruptroutine
WEITERLEITUNG:	rjmp	SET_WB_U_EXIT
DATA_BYTE_REC:	cp		YH,XH;                  ;Vergleiche YH mit XH
				brlo	INC_Y_EXIT_WEIT         ;Wenn YH < XH goto INC_Y_U_EXIT
				cp		YL,XL                   ;Vergleiche YL mit XL
				brlo	INC_Y_EXIT_WEIT         ;Wenn YL < XL goto INC_Y_U_EXIT
				mov		ZL,XL                   ;Kopiere X in Z
				mov		ZH,XH                   ;Kopiere X in Z
				rjmp	TEST_X_PLUS_0
INC_Y_EXIT_WEIT:rjmp	INC_Y_U_EXIT
TEST_X_PLUS_0:	cp		YL,ZL                   ;Vergleiche YL mit ZL
				brne	TEST_X_PLUS_1           ;Wenn YL <> ZL goto TEST_X_PLUS_1
				cp		YH,ZH                   ;Vergleiche YH mit ZH
				brne	TEST_X_PLUS_1           ;Wenn YH <> ZH goto TEST_X_PLUS_1
				mov		r0,DMX_BYTE             ;DMX_BYTE -> r0
				rjmp	INC_Y_U_EXIT            ;goto INC_Y_U_EXIT
TEST_X_PLUS_1:	adiw	r30,0x01                ;increase Z -> Z = X + 1
				cp		YL,ZL                   ;Vergleiche YL mit ZL
				brne	TEST_X_PLUS_2           ;Wenn YL <> ZL goto TEST_X_PLUS_2
				cp		YH,ZH                   ;Vergleiche YH mit ZH
				brne	TEST_X_PLUS_2           ;Wenn YH <> ZH goto TEST_X_PLUS_2
				mov		r1,DMX_BYTE             ;DMX_BYTE -> r1
				rjmp	INC_Y_U_EXIT            ;goto INC_Y_U_EXIT
TEST_X_PLUS_2:	adiw	r30,0x01                ;increase Z -> Z = X + 2
				cp		YL,ZL                   ;Vergleiche YL mit ZL
				brne	TEST_X_PLUS_3           ;Wenn YL <> ZL goto TEST_X_PLUS_3
				cp		YH,ZH                   ;Vergleiche YH mit ZH
				brne	TEST_X_PLUS_3           ;Wenn YH <> ZH goto TEST_X_PLUS_3
				mov		r2,DMX_BYTE             ;DMX_BYTE -> r2
				rjmp	INC_Y_U_EXIT            ;goto INC_Y_U_EXIT
TEST_X_PLUS_3:	adiw	r30,0x01                ;increase Z -> Z = X + 3
				cp		YL,ZL                   ;Vergleiche YL mit ZL
				brne	TEST_X_PLUS_4           ;Wenn YL <> ZL goto TEST_X_PLUS_4
				cp		YH,ZH                   ;Vergleiche YH mit ZH
				brne	TEST_X_PLUS_4           ;Wenn YH <> ZH goto TEST_X_PLUS_4
				mov		r3,DMX_BYTE             ;DMX_BYTE -> r3
				rjmp	INC_Y_U_EXIT            ;goto INC_Y_U_EXIT
TEST_X_PLUS_4:	adiw	r30,0x01                ;increase Z -> Z = X + 4
				cp		YL,ZL                   ;Vergleiche YL mit ZL
				brne	TEST_X_PLUS_5           ;Wenn YL <> ZL goto TEST_X_PLUS_5
				cp		YH,ZH                   ;Vergleiche YH mit ZH
				brne	TEST_X_PLUS_5           ;Wenn YH <> ZH goto TEST_X_PLUS_5
				mov		r4,DMX_BYTE             ;DMX_BYTE -> r4
				rjmp	INC_Y_U_EXIT            ;goto INC_Y_U_EXIT
TEST_X_PLUS_5:	adiw	r30,0x01                ;increase Z -> Z = X + 5
				cp		YL,ZL                   ;Vergleiche YL mit ZL
				brne	TEST_X_PLUS_6           ;Wenn YL <> ZL goto TEST_X_PLUS_6
				cp		YH,ZH                   ;Vergleiche YH mit ZH
				brne	TEST_X_PLUS_6           ;Wenn YH <> ZH goto TEST_X_PLUS_6
				mov		r5,DMX_BYTE             ;DMX_BYTE -> r5
				rjmp	INC_Y_U_EXIT            ;goto INC_Y_U_EXIT
TEST_X_PLUS_6:	adiw	r30,0x01                ;increase Z -> Z = X + 6
				cp		YL,ZL                   ;Vergleiche YL mit ZL
				brne	SET_WB_U_EXIT           ;Wenn YL <> ZL goto SET_WB_U_EXIT
				cp		YH,ZH                   ;Vergleiche YH mit ZH
				brne	SET_WB_U_EXIT           ;Wenn YH <> ZH goto SET_WB_U_EXIT
				mov		r6,DMX_BYTE             ;DMX_BYTE -> r6
				rjmp	INC_Y_U_EXIT            ;goto INC_Y_U_EXIT
INC_Y_U_EXIT:	adiw	r28,0x01                ;increase Y and exit Interruptroutine
				rjmp	ENDE_RX_INT
SET_WB_U_EXIT:	sbr		DMX_STATE,1             ;Set WAIT_FOR_NEXT_BREAK Bit and Exit
ENDE_RX_INT:	out		SREG,SREG_BACK
				reti



READ_DMX_START:	in		XL,PINB				;Read DMX Startadress
				com		XL
				in		XH,PIND
				com		XH
				andi	XH,0x40
				lsr		XH
				lsr		XH
				lsr		XH
				lsr		XH
				lsr		XH
				lsr		XH
				ret



SEND_PMX_BYTE:	cpi		PMX_STATE,0x00
				brne	SEND_PMX_BYTE
				inc		PMX_STATE
				ret



CHECK_LAMP_POW:	sbic	PIND,LAMP_SW				;Check manual Switch
				rjmp	CHECK_DMX_POW
				sbis	PORTD,LAMP
				rjmp	CH_LP_ON
				sbic	PORTD,LAMP
				rjmp	CH_LP_OFF
CHECK_DMX_POW:	mov		TEMP,r6						;Check DMX Command
				cpi		LAMP_POW_STATE,0x00
				breq	CH_LP_0
				cpi		LAMP_POW_STATE,0x01
				breq	CH_LP_1
				cpi		LAMP_POW_STATE,0x02
				breq	CH_LP_2
				cpi		LAMP_POW_STATE,0x03
				breq	CH_LP_3
				cpi		LAMP_POW_STATE,0x04
				breq	CH_LP_4
				rjmp	CH_LP_5
CH_LP_0:		cpi		TEMP,0x2D
				brne	CH_LP_RESET
				inc		LAMP_POW_STATE
				rjmp	CH_LP_EXIT
CH_LP_1:		cpi		TEMP,0xB6
				breq	CH_LP_1_NEXT
				cpi		TEMP,0x2D
				brne	CH_LP_RESET
				rjmp	CH_LP_EXIT
CH_LP_1_NEXT:	inc		LAMP_POW_STATE
				rjmp	CH_LP_EXIT
CH_LP_2:		cpi		TEMP,0xE2
				breq	CH_LP_2_NEXT
				cpi		TEMP,0xB6
				brne	CH_LP_RESET
				rjmp	CH_LP_EXIT
CH_LP_2_NEXT:	inc		LAMP_POW_STATE
				rjmp	CH_LP_EXIT
CH_LP_3:		cpi		TEMP,0x5D
				breq	CH_LP_3_NEXT
				cpi		TEMP,0xE2
				brne	CH_LP_RESET
				rjmp	CH_LP_EXIT
CH_LP_3_NEXT:	inc		LAMP_POW_STATE
				rjmp	CH_LP_EXIT
CH_LP_4:		cpi		TEMP,0x6A
				breq	CH_LP_4_NEXT
				cpi		TEMP,0x5D
				brne	CH_LP_RESET
				rjmp	CH_LP_EXIT
CH_LP_4_NEXT:	inc		LAMP_POW_STATE
				rjmp	CH_LP_EXIT
CH_LP_5:		cpi		TEMP,0x4B
				breq	CH_LP_ON
				cpi		TEMP,0xD9
				breq	CH_LP_OFF
				cpi		TEMP,0x6A
				brne	CH_LP_RESET
				rjmp	CH_LP_EXIT
CH_LP_ON:		rcall	LAMP_ON
				rjmp	CH_LP_RESET
CH_LP_OFF:		rcall	LAMP_OFF
				rjmp	CH_LP_RESET
CH_LP_RESET:	clr		LAMP_POW_STATE
CH_LP_EXIT:		ret



LAMP_ON:		sbic	PORTD,LAMP
				rjmp	LAMP_ON_EXIT
				cpi		LAMP_POW_LOCK,0x00
				brne	LAMP_ON_EXIT
				cli
				sbi		PORTD,LAMP
				ldi		TEMP,0x2B
				mov		POW_LOCK_COUNT_2,TEMP
				ldi		TEMP,0xF2
				mov		POW_LOCK_COUNT_1,TEMP
				ldi		TEMP,0x00
				mov		POW_LOCK_COUNT_0,TEMP
				ldi		LAMP_POW_LOCK,0xFF
				sei
LAMP_ON_EXIT:	ret



LAMP_OFF:		sbis	PORTD,LAMP
				rjmp	LAMP_OFF_EXIT
				cpi		LAMP_POW_LOCK,0x00
				brne	LAMP_OFF_EXIT
				cli
				cbi		PORTD,LAMP
				ldi		TEMP,0x83
				mov		POW_LOCK_COUNT_2,TEMP
				ldi		TEMP,0xD6
				mov		POW_LOCK_COUNT_1,TEMP
				ldi		TEMP,0x00
				mov		POW_LOCK_COUNT_0,TEMP
				ldi		LAMP_POW_LOCK,0xFF
				sei
LAMP_OFF_EXIT:	ret



RESET:			ldi		TEMP,low(RAMEND)	;Set SP to last Byte in RAM
				out		SPL,TEMP

				;Init Watchdog Timer
				ldi		TEMP,0x0D			;Enable Watchdog Timer with 0.49s Timeout
				out		WDTCR,TEMP

				;Set TRI-States
				ldi		TEMP,0x00
				out		DDRB,TEMP
				ldi		TEMP,0xFF
				out		PORTB,TEMP
				ldi		TEMP,0x2C
				out		DDRD,TEMP
				ldi		TEMP,0x55
				out		PORTD,TEMP

				;Init Variables
				ldi		TEMP,0x00			;Set Channel Registers and Current DMX Adress to 0x00
				mov		r0,TEMP
				mov		r1,TEMP
				mov		r2,TEMP
				mov		r3,TEMP
				mov		r4,TEMP
				mov		r5,TEMP
				mov		PMX_STATE,TEMP
				mov		PMX_BYTE,TEMP
				clr		LAMP_POW_STATE
				clr		LAMP_POW_LOCK
				clr		POW_LOCK_COUNT_0
				clr		POW_LOCK_COUNT_1
				clr		POW_LOCK_COUNT_2

				;Init 16 Bit Timer
				ldi		TEMP,0xFC
				out		TCNT1H,TEMP			;Set Timer Count Registers to 104,166µS (High Register first!)
				ldi		TEMP,0xCA
				out		TCNT1L,TEMP
				ldi		TEMP,0x80
				out		TIMSK,TEMP			;Enable Overfow Interrupt for Timer 1
				ldi		TEMP,0x01
				out		TCCR1B,TEMP			;Enable 16 Bit Timer with full OSC Speed

               	;Init UART for DMX Data Receive
				clr		XL					;Clear DMX Start Register
				clr		XH
				ldi		DMX_STATE,0x01		;Init DMX Status Register
				out		UBRR,DMX_STATE		;Load UART Bautrate Register with 0x01
				sbi		UCR,7				;Enable RX Interrupt
				sbi		UCR,2				;Enable 9-Bit Mode
				sbi		UCR,4				;Enable RX-UART

				sei							;Enable Globale Interrupt



MAIN:			rcall	READ_DMX_START
				wdr							;Watchdog Reset

				rcall	CHECK_LAMP_POW

				ldi		PMX_BYTE,128		;Set Channel 1
				rcall	SEND_PMX_BYTE
				mov		PMX_BYTE,r0 		;Set Channel 1 Value
				com		PMX_BYTE			;Invert Channel 1 (Iris)
				lsr		PMX_BYTE
				rcall	SEND_PMX_BYTE
				ldi		PMX_BYTE,129		;Set Channel 2
				rcall	SEND_PMX_BYTE
				mov		PMX_BYTE,r1			;Set Channel 2 Value
				lsr		PMX_BYTE
				rcall	SEND_PMX_BYTE
				ldi		PMX_BYTE,130		;Set Channel 3
				rcall	SEND_PMX_BYTE
				mov		PMX_BYTE,r2			;Set Channel 3 Value
				lsr		PMX_BYTE
				rcall	SEND_PMX_BYTE
				ldi		PMX_BYTE,131		;Set Channel 4
				rcall	SEND_PMX_BYTE
				mov		PMX_BYTE,r3			;Set Channel 4 Value
				lsr		PMX_BYTE
				rcall	SEND_PMX_BYTE
				ldi		PMX_BYTE,132		;Set Channel 5
				rcall	SEND_PMX_BYTE
				mov		PMX_BYTE,r4			;Set Channel 5 Value
				lsr		PMX_BYTE
				rcall	SEND_PMX_BYTE
				ldi		PMX_BYTE,133		;Set Channel 6
				rcall	SEND_PMX_BYTE
				mov		PMX_BYTE,r5			;Set Channel 6 Value
				lsr		PMX_BYTE
				rcall	SEND_PMX_BYTE


				;DMX Indicator Count check
				cpi		DMX_IND,0x00
				breq	MAIN_LED_OFF
				dec		DMX_IND
				sbi		PORTD,5
				rjmp	MAIN_ENDE_LED
MAIN_LED_OFF:	cbi		PORTD,5
				clr		r0
				clr		r1
				clr		r2
				clr		r3
				clr		r4
				clr		r5
MAIN_ENDE_LED:	rjmp	MAIN



.exit